快捷導(dǎo)航

ORACLE批量導(dǎo)入圖片到BLOB字段代碼示例

更新時間：2017年10月10日 09:56:33 作者：我心自明

這篇文章主要介紹了ORACLE批量導(dǎo)入圖片到BLOB字段代碼示例，此代碼示例是文章作者的項目源碼，具有一定參考價值，需要的朋友可以了解下。

要插入圖片的表不是固定的，而且是批量插入很多張，還要考慮到因為圖片的文件名錯誤，修改后要再次插入，此時應(yīng)避免已經(jīng)插入的重復(fù)執(zhí)行操作，浪費時間。

所以就選擇先用一張臨時表來暫時保存從文件系統(tǒng)讀取的照片，用DBMS_LOB的方法來處理。

第一步：創(chuàng)建一個數(shù)據(jù)庫可以訪問的目錄（注意：這個目錄是數(shù)據(jù)庫服務(wù)器上的目錄，不是客戶機上的）

-- Create directory 
create or replace directory 圖片目錄
 as 'E:\照片';

第二步：將圖片文件放入剛建好的目錄下面，不要在新建文件夾，就放在這個根目錄

第三步：根據(jù)自己的具體需求，編寫存儲過程，在做之前，我也在網(wǎng)上找了很多，但基本都只是大概說一下，沒有找到比較完整的，這里就把自己的項目源碼貼出來，供大家學(xué)習(xí)交流。

CREATE OR REPLACE PROCEDURE PRO_插入圖片(V_表名 IN VARCHAR2) IS
 P_FILENAME VARCHAR2(50); --照片名，動態(tài)拼接得到
 P_證件號碼 VARCHAR2(50);
 P_姓名   VARCHAR2(50);--這個照片名是通過姓名+證件號拼接得到的，因為基礎(chǔ)測試數(shù)據(jù)沒有提供真實的證件號碼，就選擇用手機號來代替
 P_查詢SQL VARCHAR2(500);
 P_更新SQL VARCHAR2(5000);
 P_LOB   BLOB;
 P_FILE   BFILE;
 TYPE P_REF_CURSOR IS REF CURSOR; --定義動態(tài)游標變量類型
 P_CURSOR P_REF_CURSOR; --定義動態(tài)游標變量，因為一次要插入全表的照片，所以選擇用游標來處理
 TYPE P_ROW_RECORD IS RECORD(
  證件號碼 VARCHAR2(50),
  姓名   VARCHAR2(50));
 C_ROW P_ROW_RECORD;
 V_ERR VARCHAR2(300);
BEGIN
 P_更新SQL := 'update ' || V_表名 || ' set 證件號碼=手機號碼 WHERE 證件號碼 IS NULL';
--用手機號來代替證件號碼為空的數(shù)據(jù)
 EXECUTE IMMEDIATE P_更新SQL;
 COMMIT;
 P_查詢SQL := 'SELECT 證件號碼,姓名 FROM ' || V_表名 ||
       ' WHERE 證件號碼 IS NOT NULL and 照片 IS NULL order by 證件號碼';
 OPEN P_CURSOR FOR P_查詢SQL;
 LOOP
  begin
   FETCH P_CURSOR
    INTO C_ROW;
   EXIT WHEN P_CURSOR%NOTFOUND;

--獲取證件號碼和姓名，先排除空格等臟數(shù)據(jù)，然后拼接成文件名；

   P_證件號碼 := C_ROW.證件號碼;
   P_姓名   := C_ROW.姓名;
   SELECT REPLACE(P_證件號碼, ' ', '') INTO P_證件號碼 FROM DUAL;
   SELECT substr(P_證件號碼, 1, 11) INTO P_證件號碼 FROM DUAL;
   SELECT REPLACE(P_姓名, ' ', '') INTO P_姓名 FROM DUAL;
   P_FILENAME := P_證件號碼 || P_姓名 || '.jpg';
   SELECT REPLACE(P_FILENAME, ' ', '') INTO P_FILENAME FROM DUAL;
--以下便是插入圖片的核心代碼
   INSERT INTO TA_照片總表_TEMP
    (證件號碼, 姓名, 照片)
   VALUES
    (P_證件號碼, P_姓名, EMPTY_BLOB()) RETURN 照片 INTO P_LOB;
   --獲取指定目錄下的文件
   P_FILE := BFILENAME('圖片目錄', P_FILENAME);
   --以只讀的方式打開文件
   DBMS_LOB.FILEOPEN(P_FILE, DBMS_LOB.FILE_READONLY);
   --傳遞對象
   DBMS_LOB.LOADFROMFILE(P_LOB, P_FILE, DBMS_LOB.GETLENGTH(P_FILE));
   --關(guān)閉原始文件
   DBMS_LOB.FILECLOSE(P_FILE);
   COMMIT;

--通過更新語句來向目標表插入圖片

   P_更新SQL := 'UPDATE ' || V_表名 ||
         ' A SET a.照片=(SELECT 照片 FROM TA_照片總表_TEMP b 
         WHERE A.證件號碼 = B.證件號碼 and a.姓名=b.姓名 AND ROWNUM=1)
   WHERE EXISTS (SELECT 1 FROM TA_照片總表_TEMP B WHERE A.證件號碼 = B.證件號碼 and a.姓名=b.姓名)';
   EXECUTE IMMEDIATE P_更新SQL;
   COMMIT;
  EXCEPTION

--處理異常情況，這個可以在出現(xiàn)異常時跳過異常繼續(xù)跑。正常數(shù)據(jù)依然可以插入，并且記錄異常信息，方便異常處理。這個是因為第一次寫的過程一報錯就斷掉了，本來可以插入的圖片也無法繼續(xù)，然后就做了這個優(yōu)化。

   WHEN OTHERS THEN
    rollback;
    V_ERR := SUBSTR(SQLERRM, 1, 150) || '照片名:' || P_FILENAME;

--定義一張異常信息記錄表，是一個非常好的習(xí)慣

    INSERT INTO TA_程序運行異常記錄
    VALUES
     (SQ_異常序列.NEXTVAL, 'PRO_插入圖片', V_ERR, SYSDATE);
    COMMIT;
  end;
 END LOOP;
 CLOSE P_CURSOR;
 COMMIT;
 DELETE TA_照片總表_TEMP;
 COMMIT;
END PRO_插入圖片;

總結(jié)

然后測試、運行，基本都沒問題，不過圖片的大小，很影響實際插入的時間，這個時間的優(yōu)化目前還沒有好的對策。

以上就是本文關(guān)于ORACLE批量導(dǎo)入圖片到BLOB字段代碼示例的全部內(nèi)容，希望對大家有所幫助。感興趣的朋友可以參閱：oracle 數(shù)據(jù)庫啟動階段分析、ORACLE SQL語句優(yōu)化技術(shù)要點解析、oracle中l(wèi)ength、lengthb、substr、substrb函數(shù)用法介紹等，有什么問題可以隨時留言，小編會及時回復(fù)大家的。也希望朋友們對腳本之家網(wǎng)站多多支持！

您可能感興趣的文章: