匯編實現(xiàn)簡單選擇排序的方法示例

更新時間：2020年02月04日 09:55:49 作者：this.

這篇文章主要介紹了匯編實現(xiàn)簡單選擇排序的方法示例，文中通過示例代碼介紹的非常詳細，對大家的學習或者工作具有一定的參考學習價值，需要的朋友們下面隨著小編來一起學習學習吧

上陣子重溫數(shù)據(jù)結(jié)構(gòu)，差不多更新到排序。這學期學了匯編語言，其中有幾個實驗便是實現(xiàn)內(nèi)部排序算法。以下是實現(xiàn)簡單選擇排序的程序設計：

S0 SEGMENT STACK
  DW 20 DUP(?)
TOP LABEL  WORD
S0 ENDS

S1 SEGMENT
TIP DB "Input ten number and separate the numbers with space:", 0DH, 0AH, 24H
ARY DW 20 DUP(0)
CRLF  DB 0DH, 0AH, 24H
N  DW 0
S1 ENDS



S2 SEGMENT
  ASSUME SS:S0, DS:S1, CS:S2, ES:S1
P  PROC  FAR
  MOV AX, S0
  MOV SS, AX
  LEA SP, TOP

  MOV AX, S1
  MOV DS, AX

  MOV AX, S1
  MOV ES, AX

  LEA DX, TIP
  MOV AH, 9
  INT 21H

  LEA SI, ARY

  XOR DX, DX
  MOV BL, 10
  MOV CX, 10

INPUT: MOV AH, 1
  INT 21H
  CMP AL, 20H ;空格分隔字符
  JE SAVE
  ;輸入十進制數(shù)，將數(shù)存入SI對應的內(nèi)存單元
  MOV DL, AL 
  MOV AX, [SI]
  MUL BL
  SUB DL, 30H
  ADD AL, DL
  MOV [SI], AX
  JMP INPUT
SAVE:  
  ADD SI, 2 
  LOOP  INPUT
  ;數(shù)組保存完畢

  LEA SI, ARY

  MOV DI, SI
  ADD DI, 2 ;DI位于數(shù)組的第二元素的位置

  MOV BP, 9 ;SI移動的次數(shù)和每一次比較的次數(shù)，第一次為9

GO: MOV CX, BP ;每一次比較的循環(huán)次數(shù)
  MOV BX, [SI] ;第一個數(shù)
CMPA:  CMP BX, [DI] ;比較后面的數(shù)是否比當前的小
  JBE CON ;大于就比較下一個
  MOV BX, [DI] ;將寄存器中的值替換為最小的值
  MOV AX, DI ;AX存放最小值的偏移地址
CON:  ADD DI, 2
  LOOP  CMPA

  CMP AX, 0 ;如果AX為0，則表示后面的值沒有比當前值小
  JE NO ;此時SI加一，移動到第二個數(shù) 下一次循環(huán)比較開始
CHANGE: MOV DX, [SI] ;78-83行替換當前值與最小值
  PUSH  DX
  MOV [SI], BX
  POP DX
  MOV DI, AX
  MOV [DI], DX
NO: ADD SI, 2
  MOV DI, SI
  ADD DI, 2
  CALL  PRINT
  DEC BP ;循環(huán)的次數(shù)減一
  XOR AX, AX ;清除AX的內(nèi)容，以便76行判斷
  CMP BP, 1
  JNE GO


EXIT:  MOV AH, 4CH
  INT 21H

P  ENDP

PRINT  PROC  NEAR
  PUSH  SI
  PUSH  CX
  PUSH  AX
  PUSH  DX
  LEA DX, CRLF
  MOV AH, 9
  INT 21H

  LEA SI, ARY
  MOV CX, 10
L1: MOV AX, [SI]
  MOV N, AX
  CALL  OUTPUT
  ADD SI, 2
  MOV DX, 20H
  MOV AH, 2
  INT 21H
  LOOP  L1



  POP DX
  POP AX
  POP CX
  POP SI
  RET

PRINT  ENDP

OUTPUT PROC  NEAR
  PUSH  AX
  PUSH  BX
  PUSH  CX
  PUSH  DX

  XOR CX, CX 
  MOV AX, N
  MOV BX, 10
L2: XOR DX, DX
  DIV BX
  PUSH  DX
  INC CX
  CMP AX, 0
  JNE L2

L3: POP DX
  ADD DX, 30H
  MOV AH, 2
  INT 21H
  LOOP  L3

  POP DX
  POP CX
  POP BX
  POP AX
  RET
OUTPUT ENDP

S2 ENDS
  END P