問題：假設(shè)有張學生成績表(tb)如下:
姓名 課程 分數(shù)
張三 語文 74
張三 數(shù)學 83
張三 物理 93
李四 語文 74
李四 數(shù)學 84
李四 物理 94
想變成(得到如下結(jié)果)：
姓名 語文 數(shù)學 物理
---- ---- ---- ----
李四 74 84 94
張三 74 83 93
-------------------
*/
create table tb(姓名 varchar(10) , 課程 varchar(10) , 分數(shù) int)
insert into tb values('張三' , '語文' , 74)
insert into tb values('張三' , '數(shù)學' , 83)
insert into tb values('張三' , '物理' , 93)
insert into tb values('李四' , '語文' , 74)
insert into tb values('李四' , '數(shù)學' , 84)
insert into tb values('李四' , '物理' , 94)
go
--SQL SERVER 2000 靜態(tài)SQL,指課程只有語文、數(shù)學、物理這三門課程。(以下同)
select 姓名 as 姓名 ,
max(case 課程 when '語文' then 分數(shù) else 0 end) 語文,
max(case 課程 when '數(shù)學' then 分數(shù) else 0 end) 數(shù)學,
max(case 課程 when '物理' then 分數(shù) else 0 end) 物理
from tb
group by 姓名
--SQL SERVER 2000 動態(tài)SQL,指課程不止語文、數(shù)學、物理這三門課程。(以下同)
declare @sql varchar(8000)
set @sql = 'select 姓名 '
select @sql = @sql + ' , max(case 課程 when ''' + 課程 + ''' then 分數(shù) else 0 end) [' + 課程 + ']'
from (select distinct 課程 from tb) as a
set @sql = @sql + ' from tb group by 姓名'
exec(@sql)
--SQL SERVER 2005 靜態(tài)SQL。
select * from (select * from tb) a pivot (max(分數(shù)) for 課程 in (語文,數(shù)學,物理)) b
--SQL SERVER 2005 動態(tài)SQL。
declare @sql varchar(8000)
select @sql = isnull(@sql + '],[' , '') + 課程 from tb group by 課程
set @sql = '[' + @sql + ']'
exec ('select * from (select * from tb) a pivot (max(分數(shù)) for 課程 in (' + @sql + ')) b')
---------------------------------
/*
問題：在上述結(jié)果的基礎(chǔ)上加平均分，總分，得到如下結(jié)果：
姓名 語文 數(shù)學 物理 平均分 總分
---- ---- ---- ---- ------ ----
李四 74 84 94 84.00 252
張三 74 83 93 83.33 250
*/
--SQL SERVER 2000 靜態(tài)SQL。
select 姓名 姓名,
max(case 課程 when '語文' then 分數(shù) else 0 end) 語文,
max(case 課程 when '數(shù)學' then 分數(shù) else 0 end) 數(shù)學,
max(case 課程 when '物理' then 分數(shù) else 0 end) 物理,
cast(avg(分數(shù)*1.0) as decimal(18,2)) 平均分,
sum(分數(shù)) 總分
from tb
group by 姓名
--SQL SERVER 2000 動態(tài)SQL。
declare @sql varchar(8000)
set @sql = 'select 姓名 '
select @sql = @sql + ' , max(case 課程 when ''' + 課程 + ''' then 分數(shù) else 0 end) [' + 課程 + ']'
from (select distinct 課程 from tb) as a
set @sql = @sql + ' , cast(avg(分數(shù)*1.0) as decimal(18,2)) 平均分 , sum(分數(shù)) 總分 from tb group by 姓名'
exec(@sql)
--SQL SERVER 2005 靜態(tài)SQL。
select m.* , n.平均分 , n.總分 from
(select * from (select * from tb) a pivot (max(分數(shù)) for 課程 in (語文,數(shù)學,物理)) b) m,
(select 姓名 , cast(avg(分數(shù)*1.0) as decimal(18,2)) 平均分 , sum(分數(shù)) 總分 from tb group by 姓名) n
where m.姓名 = n.姓名
--SQL SERVER 2005 動態(tài)SQL。
declare @sql varchar(8000)
select @sql = isnull(@sql + ',' , '') + 課程 from tb group by 課程
exec ('select m.* , n.平均分 , n.總分 from
(select * from (select * from tb) a pivot (max(分數(shù)) for 課程 in (' + @sql + ')) b) m ,
(select 姓名 , cast(avg(分數(shù)*1.0) as decimal(18,2)) 平均分 , sum(分數(shù)) 總分 from tb group by 姓名) n
where m.姓名 = n.姓名')
drop table tb
------------------
------------------
/*
問題：如果上述兩表互相換一下：即表結(jié)構(gòu)和數(shù)據(jù)為：
姓名 語文 數(shù)學 物理
張三 74　　83　　93
李四 74　　84　　94
想變成(得到如下結(jié)果)：
姓名 課程 分數(shù)
---- ---- ----
李四 語文 74
李四 數(shù)學 84
李四 物理 94
張三 語文 74
張三 數(shù)學 83
張三 物理 93
--------------
*/
create table tb(姓名 varchar(10) , 語文 int , 數(shù)學 int , 物理 int)
insert into tb values('張三',74,83,93)
insert into tb values('李四',74,84,94)
go
--SQL SERVER 2000 靜態(tài)SQL。
select * from
(
select 姓名 , 課程 = '語文' , 分數(shù) = 語文 from tb
union all
select 姓名 , 課程 = '數(shù)學' , 分數(shù) = 數(shù)學 from tb
union all
select 姓名 , 課程 = '物理' , 分數(shù) = 物理 from tb
) t
order by 姓名 , case 課程 when '語文' then 1 when '數(shù)學' then 2 when '物理' then 3 end
--SQL SERVER 2000 動態(tài)SQL。
--調(diào)用系統(tǒng)表動態(tài)生態(tài)。
declare @sql varchar(8000)
select @sql = isnull(@sql + ' union all ' , '' ) + ' select 姓名 , [課程] = ' + quotename(Name , '''') + ' , [分數(shù)] = ' + quotename(Name) + ' from tb'
from syscolumns
where name! = N'姓名' and ID = object_id('tb') --表名tb，不包含列名為姓名的其它列
order by colid asc
exec(@sql + ' order by 姓名 ')
--SQL SERVER 2005 動態(tài)SQL。
select 姓名 , 課程 , 分數(shù) from tb unpivot (分數(shù) for 課程 in([語文] , [數(shù)學] , [物理])) t
--SQL SERVER 2005 動態(tài)SQL，同SQL SERVER 2000 動態(tài)SQL。
--------------------
/*
問題：在上述的結(jié)果上加個平均分，總分，得到如下結(jié)果：
姓名 課程 分數(shù)
---- ------ ------
李四 語文 74.00
李四 數(shù)學 84.00
李四 物理 94.00
李四 平均分 84.00
李四 總分 252.00
張三 語文 74.00
張三 數(shù)學 83.00
張三 物理 93.00
張三 平均分 83.33
張三 總分 250.00
------------------
*/
select * from
(
select 姓名 as 姓名 , 課程 = '語文' , 分數(shù) = 語文 from tb
union all
select 姓名 as 姓名 , 課程 = '數(shù)學' , 分數(shù) = 數(shù)學 from tb
union all
select 姓名 as 姓名 , 課程 = '物理' , 分數(shù) = 物理 from tb
union all
select 姓名 as 姓名 , 課程 = '平均分' , 分數(shù) = cast((語文 + 數(shù)學 + 物理)*1.0/3 as decimal(18,2)) from tb
union all
select 姓名 as 姓名 , 課程 = '總分' , 分數(shù) = 語文 + 數(shù)學 + 物理 from tb
) t
order by 姓名 , case 課程 when '語文' then 1 when '數(shù)學' then 2 when '物理' then 3 when '平均分' then 4 when '總分' then 5 end
drop table tb

最新評論