為cmd設置密碼的批處理

更新時間：2009年05月11日 01:53:43 作者：

大家都知道，微軟的溢出漏洞真是一籮筐，而溢出自然就是要拿到CMD權限，但是如果我們的CMD要密碼的話……今天就給大家教CMD的防范方法。

CMD加密是通過批處理實現(xiàn)的，現(xiàn)在我們來新建一個記事本，然后復制下面的命令并粘貼到記事本里去，并重命名為*.bat即可?！?BR>

@echo off
if exist %windir%\fly.bat attrib -a -s -r -h %windir%\fly.bat
cls
title CMD 密碼設置
echo ================================================================================
echo                                 CMD 密碼設置
echo.
echo                               默認密碼為:123456
echo.
echo                 如需更改請在下面輸入你的密碼,不更改直接回車.........
echo.
echo ================================================================================
set paa=
set /p paa=請輸入你的新密碼:
if not defined paa call :paa
reg add "HKLM\SOFTWARE\Microsoft\Command Processor" /v AutoRun /t REG_SZ /d %windir%\fly.bat /f >nul
echo ^@echo off >%windir%\fly.bat
echo ^cls >>%windir%\fly.bat
echo title CMD-Dos 驗證............. >>%windir%\fly.bat
echo set n=3 >>%windir%\fly.bat
echo ^:start >>%windir%\fly.bat
echo ^cls >>%windir%\fly.bat
echo echo                            CMD-DOS地帶 >>%windir%\fly.bat
echo echo. >>%windir%\fly.bat
echo set pa= >>%windir%\fly.bat
echo set /p pa=請輸入密碼: >>%windir%\fly.bat
echo if /i "%%pa%%"=="%paa%" goto ok >>%windir%\fly.bat
echo set /a n-=1 >>%windir%\fly.bat
echo if "%%n%%"=="0" echo               密碼錯誤...你沒機會咯...^&ping 127.1 -n 2 ^>nul^&exit >>%windir%\fly.bat
echo echo                     密碼錯誤..你還有%%n%%機會^&ping 127.1 -n 2 ^>nul >>%windir%\fly.bat
echo goto start >>%windir%\fly.bat
echo ^:ok >>%windir%\fly.bat
echo ^cls >>%windir%\fly.bat
echo title 你可以正常使用 CMD-Dos ............. >>%windir%\fly.bat
echo echo                              歡迎進了CMD-DOS地帶 >>%windir%\fly.bat
echo cd /d c: >>%windir%\fly.bat
:stt
if not exist %windir%\fly.bat goto stt
attrib +a +s +r +h %windir%\fly.bat
cls
echo.
echo.
echo                      設置完畢.............你的密碼為:%paa%
echo.
gpupdate /force >nul
echo 任意鍵退出....
pause>nul
exit

:paa
echo 你沒有設置密碼..現(xiàn)起用默認密碼..........
set paa=123456
goto :eof