Sub 合并所有工作表_在所有行標注工作表名字_無視空行空列_考慮到不規(guī)范的多一點的行和列()
    Dim row_num As Long, column_num As Long, row_num_temp As Long, column_num_temp As Long, row_num_merge As Long, column_num_merge As Long, i As Long, arr() As Long
    Worksheets.Add.Name = "合并表"
    Sheets("合并表").Move before:=Sheets(1)
    For i = 2 To Worksheets.Count
        Worksheets(i).Activate
        'UsedRange.row，代表使用的第一個行數(shù)，在有空行的時候體現(xiàn)，同理，UsedRange.column，代表使用的第一個列數(shù)，在有空列的時候體現(xiàn)
        '那么使用第一行 + 已使用的行數(shù)，這樣可以規(guī)避頂部/左側(cè)有空行，導致獲取已使用行號的數(shù)據(jù)不符合預期（老趙，如果你看到這里不懂，就自己拆開代碼，加上空行空列體會一下）
        row_num = Worksheets(i).UsedRange.Row + Worksheets(i).UsedRange.Rows.Count - 1
        column_num = Worksheets(i).UsedRange.Column + Worksheets(i).UsedRange.Columns.Count - 1
        '如果格式很不規(guī)范，那么獲取的UsedRange.rows.count就可能是整個表格的行數(shù)，所以要規(guī)避這種情況，如果相同，就讓他減1
        If row_num = Worksheets(i).Rows.Count Then row_num = row_num - 1
        If column_num = Worksheets(i).Columns.Count Then column_num = column_num - 1
        
        '相當于遍歷所有的列，都按ctrl + ↑，取數(shù)組的最大值
        ReDim arr(1 To column_num)
        For j = LBound(arr) To UBound(arr)
            row_num_temp = Worksheets(i).Cells(row_num + 1, j).End(xlUp).Row
            arr(j) = row_num_temp
        Next
        Debug.Print (Application.WorksheetFunction.Max(arr))
        row_num_temp = Application.WorksheetFunction.Max(arr) '賦予最大值，確定最大的有數(shù)據(jù)的行數(shù)
        
        '相當于遍歷所有的行，都按ctrl + ←，取數(shù)組的最大值
        'Erase arr 清空數(shù)組，但是也可以不用，直接用ReDim也可以，如果要保留數(shù)組內(nèi)容，需要加一個preserve
        ReDim arr(1 To row_num_temp)
        For j = LBound(arr) To UBound(arr)
            column_num_temp = Worksheets(i).Cells(j, column_num + 1).End(xlToLeft).Column
            arr(j) = column_num_temp
        Next
        Debug.Print (Application.WorksheetFunction.Max(arr))
        column_num_temp = Application.WorksheetFunction.Max(arr) '賦予最大值，確定最大的有數(shù)據(jù)的列數(shù)
        
        Worksheets(i).Range(Cells(1, 1), Cells(row_num_temp, column_num_temp)).Select
        Selection.Copy Sheets("合并表").Cells(row_num_merge + 1, 2)
        Worksheets("合并表").Cells(row_num_merge + 1, 1) = Worksheets(i).Name
        row_num_merge = Sheets("合并表").UsedRange.Rows.Count
    Next
    '將首行標題轉(zhuǎn)為所有行（選擇空值，=上面的數(shù)據(jù)）
    Worksheets("合并表").Activate
    Columns("A:A").Select
    Selection.SpecialCells(xlCellTypeBlanks).Select
    Application.CutCopyMode = False
    Selection.FormulaR1C1 = "=R[-1]C"
    Columns("A:A").Select
    Selection.Copy
    Selection.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks:=False, Transpose:=False
    Application.CutCopyMode = False
    Range("A1").Select
End Sub