批處理（bat）實(shí)現(xiàn)全盤搜索指定文件獲取其完整路徑方法大全
更新時(shí)間：2014年09月04日 17:03:58 投稿：hebedich
本文總結(jié)了4種實(shí)現(xiàn)全盤搜索指定文件獲取其完整路徑的bat批處理文件源碼，有需要的朋友可以參考下
廢話不多說(shuō)，直接上代碼，額，想用的話，自己保存成bat文件即可。
【方案一】for /f + dir
@echo off
rem 指定待搜索的文件
set "FileName=BatHome_Batcher.txt"
echo 正在搜索，請(qǐng)稍候...
for %%a in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
if exist %%a:\ (
for /f "delims=" %%b in ('dir /a-d /s /b "%%a:\*%FileName%" 2^>nul') do (
if /i "%%~nxb" equ "%FileName%" (
echo,%%b
)
)
)
)
【方案二】for /r（比 for /f + dir 效率高，但不會(huì)遍歷隱藏文件）
@echo off
rem 指定待搜索的文件
set "FileName=BatHome_Batcher.txt"
echo 正在搜索，請(qǐng)稍候...
for %%a in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
if exist %%a:\ (
pushd %%a:\
for /r %%b in (*%FileName%) do (
if /i "%%~nxb" equ "%FileName%" (
echo,%%b
)
)
popd
)
)
【方案三】WMIC（Win2000/WinXP HOME版、WinXP 精簡(jiǎn)版可能不支持）
@echo off
rem 指定待搜索的文件
set "FileName=BatHome_Batcher.txt"
echo 正在搜索，請(qǐng)稍候...
for %%a in ("%FileName%") do (
set "nName=%%~na"
set "xName=%%~xa"
)
set "xName=%xName:~1%"
for /f "skip=1 delims=" %%a in ('wmic datafile where "filename='%nName%' and Extension='%xName%'" get name') do (
echo,%%a
)
【方案四】使用 Windows7 系統(tǒng)自帶的 where 命令
@echo off
rem 指定待搜索的文件
set "FileName=BatHome_Batcher.txt"
echo 正在搜索，請(qǐng)稍候...
for %%a in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
if exist %%a:\ (
for /f "delims=" %%b in ('where /r %%a: "%FileName%" 2^>nul') do (
if /i "%%~nxb" equ "%FileName%" (
echo,%%b
)
)
)
)
相關(guān)文章
刪除文件使用的命令是del，它的全稱是delete。2009-04-04
批處理寫的 oracle 數(shù)據(jù)庫(kù)備份還原工具
由于平時(shí)要進(jìn)行數(shù)據(jù)庫(kù)的備份和還原操作，為了提高效率和節(jié)省時(shí)間就有了下面的批處理程序.2009-07-07
DOS命令總共大約有一百個(gè)（包括文本編輯、查殺病毒、配置文件、批處理等）常用的也就是為數(shù)不多的一二十個(gè),我們就介紹常用的DOS命令2023-10-10
這篇文章主要介紹了用批處理bat計(jì)算上個(gè)月最后一天的日期的實(shí)現(xiàn)方法,需要的朋友可以參考下2014-07-07
BAT批處理判斷IP地址并自動(dòng)禁用啟用網(wǎng)卡
這篇文章主要介紹了BAT批處理判斷IP地址并自動(dòng)禁用啟用網(wǎng)卡,需要的朋友可以參考下2014-06-06
使用 windows bat 腳本命令一鍵啟動(dòng)MySQL服務(wù)的方法
這篇文章主要介紹了使用 windows bat 腳本命令 一鍵啟動(dòng)MySQL服務(wù)的方法,本文給大家介紹的非常詳細(xì)，對(duì)大家的學(xué)習(xí)或工作具有一定的參考借鑒價(jià)值，需要的朋友可以參考下2020-10-10
Windows下通過(guò)bat獲取網(wǎng)絡(luò)連線實(shí)際名稱,加強(qiáng)IP類設(shè)置腳本的兼容性
在之前的工作中，由于分區(qū)域管理，TCP設(shè)置有差異，所以編寫過(guò)很多關(guān)于IP切換的腳本，作為大批量電腦維護(hù)的腳本，最重要的就是兼容性，可不能就測(cè)試的那幾臺(tái)電腦通過(guò)了，然后發(fā)布給同事使用的時(shí)候，出現(xiàn)各種狀況2016-02-02
本程序運(yùn)行后自動(dòng)清除每個(gè)盤符下面的Autorun病毒本程序原理是基于讀取每個(gè)盤符下的Autorun.inf相關(guān)字段2008-08-08
ping命令的小秘密...2007-03-03
這兩者主要是保存目錄供popd使用2008-09-09