微軟應用商店無法打開怎么辦? 0x80248014錯誤的原因分析與解決方案

發(fā)布時間：2025-04-16 14:10:52 作者：佚名

近有不少小伙伴反映，Windows 10自帶的微軟商店怎么都打不開，顯示0x80248014錯誤錯誤代碼，下面我們就來看看詳細解決方案

Microsoft Store 即微軟應用商店雖然雞肋，但架不住有時候還真就得它不可。有些軟件，比如 UWP，還真只能從它這里下。不過吧，國內(nèi)版大家都知道問題也不是一般的多，比較典型的如應用商店 0x80248014 報錯，直接焊死大門讓你用不了。

接下來咱們就來嘮嘮微軟應用商店 0x80248014 該如何解決。

初步排查

在嘗試更深入的解決方法之前，我們首先進行一些基本的排查步驟，以確定是否有任何小故障可能暫時阻止了微軟商店應用的打開。這些步驟包括：

關(guān)閉系統(tǒng)上正在運行的其他應用程序，特別是那些可能干擾微軟商店運行的安全軟件。
嘗試重啟Windows個人電腦，以解決操作系統(tǒng)層面可能出現(xiàn)的臨時問題。
利用Windows的搜索功能，嘗試直接打開微軟商店應用。

若初步排查未能解決問題，我們接下來可以嘗試修復和重置微軟商店應用，以解決可能存在的臨時故障并修復受損的文件。以下是詳細的操作步驟：

修復微軟商店應用

打開“設置”：通過右鍵點擊“開始”按鈕，在彈出的菜單中選擇“設置”選項。
訪問“系統(tǒng)”：在“設置”界面中，找到并點擊“系統(tǒng)”選項，進入系統(tǒng)設置。
查找并點擊“系統(tǒng)組件”：在左側(cè)的列表中，定位并單擊“系統(tǒng)組件”選項，進入相關(guān)設置。

接下來，根據(jù)不同的系統(tǒng)版本和情況，你可能需要執(zhí)行不同的操作來修復或重置微軟商店應用。請注意，這些步驟可能因操作系統(tǒng)版本和個人電腦配置的不同而有所差異。如果你在執(zhí)行過程中遇到困難，建議查閱相關(guān)的微軟官方文檔或?qū)で髮I(yè)的技術(shù)支持。

在系統(tǒng)組件列表中，定位并點擊微軟商店應用旁邊的三個水平點，以打開其相關(guān)設置。接著，在彈出的菜單中選擇“高級選項”，以進入更深入的修復和重置選項。請注意，這些步驟可能因系統(tǒng)版本和配置的不同而有所差異，因此在實際操作時請根據(jù)具體情況進行調(diào)整。

進行修復操作：在高級選項頁面中，向下滾動并找到“修復”按鈕，點擊進行修復。請注意，此操作不會對您的應用數(shù)據(jù)造成影響。

重置微軟商店應用

若修復操作未奏效，你可嘗試對微軟商店應用進行重置：

仍于“高級選項”頁面內(nèi)，尋找到并點擊“修復”按鈕下方的“重置”選項。
在隨后的確認彈窗中，點擊“重置”以確認執(zhí)行此操作。

請注意，重置微軟商店應用將重置所有設置、清除登錄信息，并刪除所有應用數(shù)據(jù)。在執(zhí)行此操作前，請務必備份重要數(shù)據(jù)。

若上述步驟仍未能解決問題，或許需要進一步深入排查，如核查系統(tǒng)文件的完整性或更新操作系統(tǒng)。同時，確認時間和日期設置無誤也至關(guān)重要，因為錯誤的時間和日期設置可能導致應用異常。請打開“設置”，進入“時間和語言”中的“日期和時間”設置，確保時區(qū)選擇正確并開啟“自動設置時間”功能。

檢查網(wǎng)絡連接

穩(wěn)定的網(wǎng)絡是微軟商店能夠順暢打開的關(guān)鍵。請先確認設備已成功連接至互聯(lián)網(wǎng)，并嘗試重新連接以解決問題。同時，斷開與同一網(wǎng)絡的其他設備的連接，重啟路由器可能有助于改善網(wǎng)絡狀況。

清除微軟商店緩存

緩存問題常常導致微軟商店應用出現(xiàn)故障。你可以通過按下Win+R鍵打開“運行”對話框，輸入wsreset并點擊“確定”，來清除微軟商店的緩存。清除后，重新啟動微軟商店，看看問題是否得到解決。

這將啟動一個空白的Windows命令提示符窗口，表明正在清除微軟商店的緩存。請耐心等待大約30秒，直至該過程完全結(jié)束。

關(guān)閉代理服務

代理設置有時會干擾某些應用程序和服務的正常運行。為了解決這一問題，請進入“設置”>“網(wǎng)絡和互聯(lián)網(wǎng)”>“代理”，然后關(guān)閉代理服務。

安裝可用的Windows更新

確保您的Windows系統(tǒng)已安裝最新的更新，這有助于修復微軟商店應用可能遇到的問題。請打開“設置”>“Windows更新”，檢查并安裝任何可用的更新。

重新安裝微軟商店

如果常規(guī)的修復方法均無法解決問題，您可以嘗試卸載并重新安裝微軟商店。請注意，此操作將移除關(guān)鍵的Windows組件，因此應謹慎進行。與普通應用程序不同，微軟商店的卸載和安裝過程需要特殊的操作步驟。以下是指南：

卸載微軟商店應用

首先，打開PowerShell。您可以在Windows搜索中輸入“PowerShell”來找到并運行它。接著，以管理員身份運行PowerShell，并在用戶賬戶控制窗口中選擇“是”以確認操作。在PowerShell窗口中，粘貼并執(zhí)行以下命令以卸載微軟商店：

Get-AppxPackage WindowsStore | Remove-AppxPackage

重啟設備

成功執(zhí)行卸載命令后，請關(guān)閉PowerShell并重啟您的計算機。

重新安裝微軟商店應用

設備重啟后，再次以管理員身份運行PowerShell，并在窗口中粘貼執(zhí)行以下命令以重新安裝微軟商店：

Get-AppxPackage -AllUsers | Foreach {Add-AppxPackage -DisableDevelopmentMode -Register "$($_.InstallLocation)\AppXManifest.xml"}

請注意，這些步驟可能因Windows版本的不同而有所差異。在執(zhí)行任何操作之前，請確保您已備份重要數(shù)據(jù)，以防意外發(fā)生。

重新安裝微軟商店

在執(zhí)行上述操作后，您可能需要重新安裝微軟商店應用。請注意，這可能會影響您已安裝的其他應用程序，因此在操作完成后，請仔細檢查并重新安裝可能受到影響的程序。如果您在執(zhí)行這些步驟時遇到任何困難，建議聯(lián)系微軟官方支持以獲取專業(yè)幫助。

應用商店 0x80248014 報錯解決辦法

重置微軟商店權(quán)限

Win+X 打開菜單，找到并單擊打開“Windows Powershell（管理員）”輸入以下命令并回車：

icacls “C：\Program Files\WindowsApps” /reset /t /c /q

重置 Windows 更新組件

以上方法沒能解決應用商店 0x80248014 錯誤，就來試試以下命令：

net&nbsp;stop wuauserv

net&nbsp;stop cryptSvc

net&nbsp;stop bits

ren&nbsp;C:\Windows\SoftwareDistribution SoftwareDistribution.old

ren&nbsp;C:\Windows\System32\catroot2 Catroot2.old

net&nbsp;start wuauserv

net&nbsp;start cryptSvc

net&nbsp;start bits

netsh&nbsp;winsock reset

注意：以上命令需逐條輸入逐條回車執(zhí)行，切勿直接全部復制運行；全部執(zhí)行完畢后請重啟電腦。

重置 Windows 更新組件（進階）

如果以上方法均無效，那么小江只能祭出殺招了，以下方法由國外玩家使用后證明有效。

注意：該方法適用于Win10，Win11未經(jīng)測試；執(zhí)行以下腳本后電腦會重啟，請?zhí)崆氨４婧觅Y料。

@echo off
:: Created by: Shawn Brink
:: Created on: October 1, 2015
:: Updated on: March 8, 2021
:: Tutorial: https://www.tenforums.com/tutorials/24742-reset-windows-update-windows-10-a.html
:: Prompt to Run as administrator
Set "Variable=0" & if exist "%temp%\getadmin.vbs" del "%temp%\getadmin.vbs"
fsutil dirty query %systemdrive%  >nul 2>&1 && goto :(Privileges_got)
If "%1"=="%Variable%" (echo. &echo. Please right-click on the file and select &echo. "Run as administrator". &echo. Press any key to exit. &pause>nul 2>&1& exit)
cmd /u /c echo Set UAC = CreateObject^("Shell.Application"^) : UAC.ShellExecute "%~0", "%Variable%", "", "runas", 1 > "%temp%\getadmin.vbs"&cscript //nologo "%temp%\getadmin.vbs" & exit
:(Privileges_got)
:: Checking and Stopping the Windows Update services
set b=0
:bits
set /a b=%b%+1
if %b% equ 3 (
   goto end1
) 
net stop bits
echo Checking the bits service status.
sc query bits | findstr /I /C:"STOPPED" 
if not %errorlevel%==0 ( 
    goto bits 
) 
goto loop2
:end1
cls
echo.
echo Cannot reset Windows Update since "Background Intelligent Transfer Service" (bits) service failed to stop. Please restart the computer, and try again.
echo.
pause
goto Start
:loop2
set w=0
:wuauserv
set /a w=%w%+1
if %w% equ 3 (
   goto end2
) 
net stop wuauserv
echo Checking the wuauserv service status.
sc query wuauserv | findstr /I /C:"STOPPED" 
if not %errorlevel%==0 ( 
    goto wuauserv 
) 
goto loop3
:end2
cls
echo.
echo Cannot reset Windows Update since "Windows Update" (wuauserv) service failed to stop. Please restart the computer, and try again.
echo.
pause
goto Start
:loop3
set app=0
:appidsvc
set /a app=%app%+1
if %app% equ 3 (
   goto end3
) 
net stop appidsvc
echo Checking the appidsvc service status.
sc query appidsvc | findstr /I /C:"STOPPED" 
if not %errorlevel%==0 ( 
    goto appidsvc 
) 
goto loop4
:end3
cls
echo.
echo Cannot reset Windows Update since "Application Identity" (appidsvc) service failed to stop. Please restart the computer, and try again.v
echo.
pause
goto Start
:loop4
set c=0
:cryptsvc
set /a c=%c%+1
if %c% equ 3 (
   goto end4
) 
net stop cryptsvc
echo Checking the cryptsvc service status.
sc query cryptsvc | findstr /I /C:"STOPPED" 
if not %errorlevel%==0 ( 
    goto cryptsvc 
) 
goto Reset
:end4
cls
echo.
echo Cannot reset Windows Update since "Cryptographic Services" (cryptsvc) service failed to stop. Please restart the computer, and try again.
echo.
pause
goto Start
:Reset
Ipconfig /flushdns
del /s /q /f "%ALLUSERSPROFILE%\Application Data\Microsoft\Network\Downloader\qmgr*.dat" 
del /s /q /f "%ALLUSERSPROFILE%\Microsoft\Network\Downloader\qmgr*.dat"
del /s /q /f "%SYSTEMROOT%\Logs\WindowsUpdate\*"
if exist "%SYSTEMROOT%\winsxs\pending.xml.bak" del /s /q /f "%SYSTEMROOT%\winsxs\pending.xml.bak" 
if exist "%SYSTEMROOT%\winsxs\pending.xml" ( 
    takeown /f "%SYSTEMROOT%\winsxs\pending.xml" 
    attrib -r -s -h /s /d "%SYSTEMROOT%\winsxs\pending.xml" 
    ren "%SYSTEMROOT%\winsxs\pending.xml" pending.xml.bak 
) 
if exist "%SYSTEMROOT%\SoftwareDistribution.bak" rmdir /s /q "%SYSTEMROOT%\SoftwareDistribution.bak"
if exist "%SYSTEMROOT%\SoftwareDistribution" ( 
    attrib -r -s -h /s /d "%SYSTEMROOT%\SoftwareDistribution" 
    ren "%SYSTEMROOT%\SoftwareDistribution" SoftwareDistribution.bak 
) 
if exist "%SYSTEMROOT%\system32\Catroot2.bak" rmdir /s /q "%SYSTEMROOT%\system32\Catroot2.bak" 
if exist "%SYSTEMROOT%\system32\Catroot2" ( 
    attrib -r -s -h /s /d "%SYSTEMROOT%\system32\Catroot2" 
    ren "%SYSTEMROOT%\system32\Catroot2" Catroot2.bak 
) 
:: Reset Windows Update policies
reg delete "HKCU\SOFTWARE\Policies\Microsoft\Windows\WindowsUpdate" /f
reg delete "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Policies\WindowsUpdate" /f
reg delete "HKLM\SOFTWARE\Policies\Microsoft\Windows\WindowsUpdate" /f
reg delete "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Policies\WindowsUpdate" /f
gpupdate /force
:: Reset the BITS service and the Windows Update service to the default security descriptor
sc.exe sdset bits D:(A;;CCLCSWRPWPDTLOCRRC;;;SY)(A;;CCDCLCSWRPWPDTLOCRSDRCWDWO;;;BA)(A;;CCLCSWLOCRRC;;;AU)(A;;CCLCSWRPWPDTLOCRRC;;;PU)
sc.exe sdset wuauserv D:(A;;CCLCSWRPWPDTLOCRRC;;;SY)(A;;CCDCLCSWRPWPDTLOCRSDRCWDWO;;;BA)(A;;CCLCSWLOCRRC;;;AU)(A;;CCLCSWRPWPDTLOCRRC;;;PU)
:: Reregister the BITS files and the Windows Update files
cd /d %windir%\system32
regsvr32.exe /s atl.dll 
regsvr32.exe /s urlmon.dll 
regsvr32.exe /s mshtml.dll 
regsvr32.exe /s shdocvw.dll 
regsvr32.exe /s browseui.dll 
regsvr32.exe /s jscript.dll 
regsvr32.exe /s vbscript.dll 
regsvr32.exe /s scrrun.dll 
regsvr32.exe /s msxml.dll 
regsvr32.exe /s msxml3.dll 
regsvr32.exe /s msxml6.dll 
regsvr32.exe /s actxprxy.dll 
regsvr32.exe /s softpub.dll 
regsvr32.exe /s wintrust.dll 
regsvr32.exe /s dssenh.dll 
regsvr32.exe /s rsaenh.dll 
regsvr32.exe /s gpkcsp.dll 
regsvr32.exe /s sccbase.dll 
regsvr32.exe /s slbcsp.dll 
regsvr32.exe /s cryptdlg.dll 
regsvr32.exe /s oleaut32.dll 
regsvr32.exe /s ole32.dll 
regsvr32.exe /s shell32.dll 
regsvr32.exe /s initpki.dll 
regsvr32.exe /s wuapi.dll 
regsvr32.exe /s wuaueng.dll 
regsvr32.exe /s wuaueng1.dll 
regsvr32.exe /s wucltui.dll 
regsvr32.exe /s wups.dll 
regsvr32.exe /s wups2.dll 
regsvr32.exe /s wuweb.dll 
regsvr32.exe /s qmgr.dll 
regsvr32.exe /s qmgrprxy.dll 
regsvr32.exe /s wucltux.dll 
regsvr32.exe /s muweb.dll 
regsvr32.exe /s wuwebv.dll
regsvr32.exe /s wudriver.dll
netsh winsock reset
netsh winsock reset proxy
:: Set the startup type as automatic
sc config wuauserv start= auto
sc config bits start= auto 
sc config DcomLaunch start= auto 
:Start
net start bits
net start wuauserv
net start appidsvc
net start cryptsvc
:: Restart computer
cls
echo It is required to restart the computer to finish resetting Windows Update.
echo.
echo Please save and close anything open now, before the computer is restarted.
echo.
pause
echo.
echo.
echo.
echo *** Restart computer now. ***
echo.
pause
shutdown /r /f /t 0

1、復制上方代碼，保存為.bat腳本（在新打開的頁面右鍵另存為，并將.txt改為.bat），雙擊打開，必要時以管理員身份運行；

2、如未遭遇異常在全部操作執(zhí)行完畢后電腦會自行關(guān)機重啟；

3、如遭遇異常無法執(zhí)行命令，會提示按下任意鍵以繼續(xù)，按下任意鍵后.bat 文件將重新啟之前已停止的服務而不會重啟電腦。